Posição do ponto de ancoragem relativo ao objeto será selecionado a partir do ENUM_ARROW_ANCHOR.
As setas grandes (mais do que 5) somente serão criadas pela configuração de valores apropriados da propriedade OBJPROP_WIDTH quando escrever um código no MetaEditor.
O tipo de seta necessário podem ser selecionado, definindo um dos códigos dos símbolos da fonte Wingdings.
Exemplo
O seguinte script cria um objeto Seta no gráfico e altera seu tipo. Funções especiais têm sido desenvolvidas para criar e alterar as propriedades do objeto gráfico. Você pode utilizar estas funções "as is" em seus próprios aplicativos.
//--- descrição
#property description "Script cria uma seta aleatória na janela do gráfico."
#property description "Coordenadas do ponto de ancoragem é definido em"
#property description "porcentagem do tamanho da janela de gráfico."
//--- janela de exibição dos parâmetros de entrada durante inicialização do script
#property script_show_inputs
//--- entrada de parâmetros do script
input string InpName="Arrow"; // Nome da seta
input int InpDate=50; // Ponto de ancoragem da data em %
input int InpPrice=50; // Ponto de ancoragem do preço em %
input ENUM_ARROW_ANCHOR InpAnchor=ANCHOR_TOP; // Tipo de ancoragem
input color InpColor=clrDodgerBlue; // Cor da seta
input ENUM_LINE_STYLE InpStyle=STYLE_SOLID; // Estilo de linha da borda
input int InpWidth=10; // Tamanho da seta
input bool InpBack=false; // Seta do fundo
input bool InpSelection=false; // Destaque para mover
input bool InpHidden=true; // Ocultar na lista de objeto
input long InpZOrder=0; // Prioridade para clicar no mouse
//+------------------------------------------------------------------+
//| Criar a seta |
//+------------------------------------------------------------------+
bool ArrowCreate(const long chart_ID=0, // ID do gráfico
const string name="Arrow", // nome da seta
const int sub_window=0, // índice da sub-janela
datetime time=0, // ponto de ancoragem do tmepo
double price=0, // ponto de ancoragem do preço
const uchar arrow_code=252, // código da seta
const ENUM_ARROW_ANCHOR anchor=ANCHOR_BOTTOM, // posição do ponto de ancoragem
const color clr=clrRed, // cor da seta
const ENUM_LINE_STYLE style=STYLE_SOLID, // estilo da linha da borda
const int width=3, // tamanho da seta
const bool back=false, // no fundo
const bool selection=true, // destaque para mover
const bool hidden=true, // ocultar na lista de objeto
const long z_order=0) // prioridade para clicar no mouse
{
//--- definir as coordenadas de pontos de ancoragem, se eles não estão definidos
ChangeArrowEmptyPoint(time,price);
//--- redefine o valor de erro
ResetLastError();
//--- criar uma seta
if(!ObjectCreate(chart_ID,name,OBJ_ARROW,sub_windo w,time,price))
{
Print(__FUNCTION__,
": falha ao criar uma seta! Código de erro = ",GetLastError());
return(false);
}
//--- definir o código da seta
ObjectSetInteger(chart_ID,name,OBJPROP_ARROWCODE,a rrow_code);
//--- tipo de definição de ancoragem
ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anch or);
//--- definir a cor da seta
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- definir o estilo da linha da borda
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style );
//--- definir o tamanho da seta
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width );
//--- exibir em primeiro plano (false) ou fundo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- habilitar (true) ou desabilitar (true) o modo do movimento da seta com o mouse
//--- ao criar um objeto gráfico usando a função ObjectCreate, o objeto não pode ser
//--- destacado e movimentado por padrão. Dentro deste método, o parâmetro de seleção
//--- é verdade por padrão, tornando possível destacar e mover o objeto
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE, selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,se lection);
//--- ocultar (true) ou exibir (false) o nome do objeto gráfico na lista de objeto
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidd en);
//--- definir a prioridade para receber o evento com um clique do mouse no gráfico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_or der);
//--- sucesso na execução
return(true);
}
//+------------------------------------------------------------------+
//| Mover ponto de ancoragem |
//+------------------------------------------------------------------+
bool ArrowMove(const long chart_ID=0, // ID do gráfico
const string name="Arrow", // nome do objeto
datetime time=0, // coordenada do ponto de ancoragem de tempo
double price=0) // coordenada do ponto de ancoragem de preço
{
//--- se a posição do ponto não está definida, mover para a barra atual tendo o preço Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- redefine o valor de erro
ResetLastError();
//--- mover o ponto de ancoragem
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": falha ao mover o ponto de ancoragem! Código de erro = ",GetLastError());
return(false);
}
//--- sucesso na execução
return(true);
}
//+------------------------------------------------------------------+
//| Alterar o código da seta |
//+------------------------------------------------------------------+
bool ArrowCodeChange(const long chart_ID=0, // ID do gráfico
const string name="Arrow", // nome do objeto
const uchar code=252) // código da seta
{
//--- redefine o valor de erro
ResetLastError();
//--- alterar o código da seta
if(!ObjectSetInteger(chart_ID,name,OBJPROP_ARROWCO DE,code))
{
Print(__FUNCTION__,
": falha ao alterar o código da seta! Código de erro = ",GetLastError());
return(false);
}
//--- sucesso na execução
return(true);
}
//+------------------------------------------------------------------+
//| Alterar tipo de ancoragem |
//+------------------------------------------------------------------+
bool ArrowAnchorChange(const long chart_ID=0, // ID do gráfico
const string name="Arrow", // nome do objeto
const ENUM_ARROW_ANCHOR anchor=ANCHOR_TOP) // tipo de ancoragem
{
//--- redefine o valor de erro
ResetLastError();
//--- alterar tipo de ancoragem
if(!ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR, anchor))
{
Print(__FUNCTION__,
": falha para alterar o tipo de ancoragem! Código de erro = ",GetLastError());
return(false);
}
//--- sucesso na execução
return(true);
}
//+------------------------------------------------------------------+
//| Excluir uma seta |
//+------------------------------------------------------------------+
bool ArrowDelete(const long chart_ID=0, // ID do gráfico
const string name="Arrow") // nome da seta
{
//--- redefine o valor de erro
ResetLastError();
//--- excluir uma seta
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": falha ao excluir uma seta! Código de erro = ",GetLastError());
return(false);
}
//--- sucesso na execução
return(true);
}
//+------------------------------------------------------------------+
//| Verificar valores de ponto de ancoragem e definir valores padrão |
//| para aqueles vazios |
//+------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
{
//--- se o tempo do ponto não está definido, será na barra atual
if(!time)
time=TimeCurrent();
//--- se o preço do ponto não está definido, ele terá valor Bid
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Programa Script da função start (iniciar) |
//+------------------------------------------------------------------+
void OnStart()
{
//--- verificar a exatidão dos parâmetros de entrada
if(InpDate<0 || InpDate>100 || InpPrice<0 || InpPrice>100)
{
Print("Erro! Valores incorretos dos parâmetros de entrada!");
return;
}
//--- número de barras visíveis na janela do gráfico
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- tamanho do array de preço
int accuracy=1000;
//--- arrays para armazenar data e valores de preço para serem usados
//--- para definir e alterar sinal das coordenadas do ponto de ancoragem
datetime date[];
double price[];
//--- alocação de memória
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- preencher o array das datas
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Falha ao copiar valores de tempo! Código de erro = ",GetLastError());
return;
}
//--- preencher o array de preços
//--- encontrar os maiores e menores valores do gráfico
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- definir uma etapa de mudança de um preço e preencher o array
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- definir pontos para desenhar a seta
int d=InpDate*(bars-1)/100;
int p=InpPrice*(accuracy-1)/100;
//--- criar uma seta no gráfico
if(!ArrowCreate(0,InpName,0,date[d],price[p],32,InpAnchor,InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpHidden,I npZOrder))
{
return;
}
//--- redesenhar o gráfico
ChartRedraw();
//--- analisar todos os casos de criação de setas no loop
for(int i=33;i<256;i++)
{
if(!ArrowCodeChange(0,InpName,(uchar)i))
return;
//--- verificar se o funcionamento do script foi desativado a força
if(IsStopped())
return;
//--- redesenhar o gráfico
ChartRedraw();
// meio segundo de atraso
Sleep(500);
}
//--- 1 segundo de atraso
Sleep(1000);
//--- excluir a seta do gráfico
ArrowDelete(0,InpName);
ChartRedraw();
//--- 1 segundo de atraso
Sleep(1000);
//---
}
