Name:  objganngrid.png
Views: 106
Size:  7.0 KB

Observação

Para Grade Gann, é possível determinar o tipo de tendência a partir do enumerador ENUM_GANN_DIRECTION. Ao ajustar o valor da escala(OBJPROP_SCALE), é possível alterar o ângulo de inclinação das linhas do grade.

Exemplo

O seguinte script cria e move o Grade Gann no gráfico. Funções especiais têm sido desenvolvidas para criar e alterar as propriedades do objeto gráfico. Você pode utilizar estas funções "as is" em seus próprios aplicativos.





//--- descrição
#property description "Script desenha o objeto gráfico tipo \"Grade Gann\"."
#property description "Coordenadas dos pontos de ancoragem do grade são definidos em percentagem do"
#property description "tamanho da janela do gráfico."
//--- janela de exibição dos parâmetros de entrada durante inicialização do script
#property script_show_inputs
//--- entrada de parâmetros do script
input string InpName="GannGrid"; // Nome do grade
input int InpDate1=15; // Data do 1º ponto, %
input int InpPrice1=25; // Preço do 1º ponto, %
input int InpDate2=35; // Data do 2º ponto, %
input double InpScale=3.0; // Escala
input bool InpDirection=false; // Direção da tendência
input color InpColor=clrRed; // Cor do grade
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Estilo de linhas do grade
input int InpWidth=1; // Largura das linhas fan
input bool InpBack=false; // Grade de fundo
input bool InpSelection=true; // Destaque para mover
input bool InpHidden=true; // Ocultar na lista de objeto
input long InpZOrder=0; // Prioridade para clicar no mouse
//+------------------------------------------------------------------+
//| Criar Grade Gann |
//+------------------------------------------------------------------+
bool GannGridCreate(const long chart_ID=0, // ID de gráfico
const string name="GannGrid", // nome do grade
const int sub_window=0, // índice da sub-janela
datetime time1=0, // primeiro ponto de tempo
double price1=0, // primeiro ponto de preço
datetime time2=0, // segundo ponto de tempo
const double scale=1.0, // escala
const bool direction=true, // direção da tendência
const color clr=clrRed, // cor do grade
const ENUM_LINE_STYLE style=STYLE_SOLID, // estilo das linhas grade
const int width=1, // largura das linhas grade
const bool back=false, // no fundo
const bool selection=true, // destaque para mover
const bool hidden=true, // ocultar na lista de objetos
const long z_order=0) // prioridade para o clique do mouse
{
//--- definir coordenadas de pontos de ancoragem, se eles não estão definidos
ChangeGannGridEmptyPoints(time1,price1,time2);
//--- redefine o valor de erro
ResetLastError();
//--- Criar Grade Gann pelas coordenadas fornecidas
if(!ObjectCreate(chart_ID,name,OBJ_GANNGRID,sub_wi ndow,time1,price1,time2,0))
{
Print(__FUNCTION__,
": falha ao criar \"Grade Gann\"! Código de erro = ",GetLastError());
return(false);
}
//--- alterar a escala (número de pips por barra)
ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale) ;
//--- mudar a direção de tendência Gann Fan (true - descendente, false - ascendente)
ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,d irection);
//--- definir cor do grade
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- definir a exibição do estilo das linhas grade
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style );
//--- definir a largura da linha do grade
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width );
//--- exibir em primeiro plano (false) ou fundo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- habilitar (true) ou desabilitar (false) o modo de destaque para mover o grid
//--- ao criar um objeto gráfico usando a função ObjectCreate, o objeto não pode ser
//--- destacado e movimentado por padrão. Dentro deste método, o parâmetro de seleção
//--- é verdade por padrão, tornando possível destacar e mover o objeto
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE, selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,se lection);
//--- ocultar (true) ou exibir (false) o nome do objeto gráfico na lista de objeto
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidd en);
//--- definir a prioridade para receber o evento com um clique do mouse no gráfico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_or der);
//--- sucesso na execução
return(true);
}
//+------------------------------------------------------------------+
//| Mover ponto de ancoragem do Grade Gann |
//+------------------------------------------------------------------+
bool GannGridPointChange(const long chart_ID=0, // ID do gráfico
const string name="GannGrid", // nome do grade
const int point_index=0, // índice do ponto de ancoragem
datetime time=0, // coordenada do ponto de ancoragem de tempo
double price=0) // coordenada do ponto de ancoragem de preço
{
//--- se a posição do ponto não está definida, mover para a barra atual tendo o preço Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- redefine o valor de erro
ResetLastError();
//--- mover ponto de ancoragem do grade
if(!ObjectMove(chart_ID,name,point_index,time,pric e))
{
Print(__FUNCTION__,
": falha ao mover o ponto de ancoragem! Código de erro = ",GetLastError());
return(false);
}
//--- sucesso na execução
return(true);
}
//+------------------------------------------------------------------+
//| Alterar a escala Grade Gann |
//+------------------------------------------------------------------+
bool GannGridScaleChange(const long chart_ID=0, // ID do gráfico
const string name="GannGrid", // nome do grade
const double scale=1.0) // escala
{
//--- redefine o valor de erro
ResetLastError();
//--- alterar a escala (número de pips por barra)
if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,sc ale))
{
Print(__FUNCTION__,
": falha ao alterar a escala! Código de erro = ",GetLastError());
return(false);
}
//--- sucesso na execução
return(true);
}
//+------------------------------------------------------------------+
//| Alterar a direção de tendência Grade Gann |
//+------------------------------------------------------------------+
bool GannGridDirectionChange(const long chart_ID=0, // ID do gráfico
const string name="GannGrid", // nome do grade
const bool direction=true) // direção da tendência
{
//--- redefine o valor de erro
ResetLastError();
//--- alterar a direção de tendência Grade Gann
if(!ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTI ON,direction))
{
Print(__FUNCTION__,
": falha ao alterar a direção de tendência! Código de erro = ",GetLastError());
return(false);
}
//--- sucesso na execução
return(true);
}
//+------------------------------------------------------------------+
//| A função remove o Gann Fan do gráfico |
//+------------------------------------------------------------------+
bool GannGridDelete(const long chart_ID=0, // ID do gráfico
const string name="GannGrid") // nome do grade
{
//--- redefine o valor de erro
ResetLastError();
//--- excluir Grade Gann
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": falha ao excluir \"Grade Gann\"! Código de erro = ",GetLastError());
return(false);
}
//--- sucesso na execução
return(true);
}
//+------------------------------------------------------------------+
//| Ver valores dos pontos de ancoragem do Grade Gann e definir |
//| valores padrão para aqueles vazios |
//+------------------------------------------------------------------+
void ChangeGannGridEmptyPoints(datetime &time1,double &price1,datetime &time2)
{
//--- se o tempo do primeiro ponto não está definido, será na barra atual
if(!time2)
time2=TimeCurrent();
//--- se o tempo do primeiro ponto não está definido, está localizado 9 barras a esquerda partir da segunda
if(!time1)
{
//--- array para receber o tempo de abertura das últimos 10 barras
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- definir o primeiro ponto 9 barras a esquerda do segundo
time1=temp[0];
}
//--- se o preço do primeiro ponto não está definido, ele terá valor Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Programa Script da função start (iniciar) |
//+------------------------------------------------------------------+
void OnStart()
{
//--- verificar a exatidão dos parâmetros de entrada
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("Erro! Valores incorretos dos parâmetros de entrada!");
return;
}
//--- número de barras visíveis na janela do gráfico
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- tamanho do array de preço
int accuracy=1000;
//--- arrays para armazenar data e valores de preço para serem usados
//--- para definir e alterar as coordenadas de pontos de ancoragem do grade
datetime date[];
double price[];
//--- alocação de memória
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- preencher o array das datas
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Falha ao copiar valores de tempo! Código de erro = ",GetLastError());
return;
}
//--- preencher o array de preços
//--- encontrar os maiores e menores valores do gráfico
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- definir uma etapa de mudança de um preço e preencher o array
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- definir os pontos para desenhar Grade Gann
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- criar Grade Gann
if(!GannGridCreate(0,InpName,0,date[d1],price[p1],date[d2],InpScale,InpDirection,
InpColor,InpStyle,InpWidth,InpBack,InpSelection,In pHidden,InpZOrder))
{
return;
}
//--- redesenhar o gráfico e esperar por um segundo
ChartRedraw();
Sleep(1000);
//--- agora, mover os pontos de ancoragem do grade
//--- contador de loop
int v_steps=accuracy/4;
//--- mover o primeiro ponto de ancoragem vertical
for(int i=0;i<v_steps;i++)
{
//--- usar o seguinte valor
if(p1<accuracy-1)
p1+=1;
if(!GannGridPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- verificar se o funcionamento do script foi desativado a força
if(IsStopped())
return;
//--- redesenhar o gráfico
ChartRedraw();
}
//--- 1 segundo de atraso
Sleep(1000);
//--- contador de loop
int h_steps=bars/4;
//--- mover o segundo ponto de ancoragem vertical
for(int i=0;i<h_steps;i++)
{
//--- usar o seguinte valor
if(d2<bars-1)
d2+=1;
if(!GannGridPointChange(0,InpName,1,date[d2],0))
return;
//--- verificar se o funcionamento do script foi desativado a força
if(IsStopped())
return;
//--- redesenhar o gráfico
ChartRedraw();
// 0.05 segundos de atraso
Sleep(50);
}
//--- 1 segundo de atraso
Sleep(1000);
//--- alterar a direção tendência do grade para um descendente
GannGridDirectionChange(0,InpName,true);
//--- redesenhar o gráfico
ChartRedraw();
//--- 1 segundo de atraso
Sleep(1000);
//--- excluir o grade do gráfico
GannGridDelete(0,InpName);
ChartRedraw();
//--- 1 segundo de atraso
Sleep(1000);
//---
}